list file with file size

[xhai]

Hi guys can you improve this code

Code: Select all

dir /a-d /b *.pdf>Pdflist.txt

1. I would like to list the pdf files + the size of the pdf + with no.
simulate
1. Make-me-smile.pdf [20MB]
2. Make-me-cry.pdf [950kb]
etc.
2. Now that i have a list of pdf file with size I want to add my .doc files
simulate
1. Make-me-smile.pdf [20MB]
2. Make-me-cry.doc [950kb]
etc.
Thank You.. It may sound simple but it's hard for me to code..

[foxidrive]

Does it matter how the filesizes are calculated?

1024 = 1 kB
or 1000 = 1kB
or just rounded?

[xhai]

Does it matter how the filesizes are calculated?

1024 = 1 kB
or 1000 = 1kB
or just rounded?

Thanks Foxi for fast reply.. any method as long it is acurate

[foxidrive]

Is rounded decimal good enough?

"Accurate" here depends on your needs.

[Yury]

Code: Select all

@echo off
set "folder=."
set "extensions=*.pdf *.doc"
for /f "delims=" %%i in ('
 mshta "javascript:new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write('\t')&close()"
') do (
 set TAB=%%i
 )
(
for /f "tokens=* delims=%TAB% " %%i in ('
 robocopy "%folder%" %random% %extensions% /nc /ndl /njh /njs /l
') do (
 set /a n+=1
 for /f "tokens=1,2 delims=%TAB%" %%j in ("%%i") do (
  for /f "tokens=1,2" %%l in ("%%j") do (
   if "%%m"=="" (
    if %%j lss 1024 (
     call echo %%n%%. %%~nxk [%%j B]
     ) else (
     set /a x=%%j0/1024
     call echo %%n%%. %%~nxk [%%x:~,-1%%.%%x:~-1%% kB]
     ) 
    ) else (
    if %%m==m (
     call echo %%n%%. %%~nxk [%%l MB]
     )
    if %%m==g (
     call echo %%n%%. %%~nxk [%%l GB]
     )
    )
   )
  )
 )
)>"list.txt"
exit /b

[foxidrive]

Nice work Yury.

[xhai]

HI Yury Why so happen the code doesn't work with me... it give me black screen after a few minutes it close.. My OS is window 7

[ShadowThief]

<code>

HI Yury Why so happen the code doesn't work with me... it give me black screen after a few minutes it close.. My OS is window 7

You see no text on the screen because the output is being put in a file.

[Squashman]

Works Perfect Yury!

[xhai]

Works Perfect Yury!

Still no luck I can find the output Pdflist.txt in the same directory as the bat file...

[Squashman]

Works Perfect Yury!

Still no luck I can find the output Pdflist.txt in the same directory as the bat file...

What are you talking about. The code clearly shows that the output is list.txt!

[xhai]

Works Perfect Yury!

Still no luck I can find the output Pdflist.txt in the same directory as the bat file...

What are you talking about. The code clearly shows that the output is list.txt!

Ya Thanks Yuri code work.. I was so dumb I'm looking at the wrong output..