Recursive copy from text list

[carnagel]

Hi,

Looking to batch copy a list of files from a text list, recursively through all sub-directories please.

I have a working batch for a single directory - just need the recursive added, if possible.

Code: Select all

@echo off
set Source=D:\mydirectory\myfiles
set Target=D:\tmp
set FileList=C:\Users\Administrator\Desktop\move.txt
echo.

if not exist "%Source%" echo Source folder "%Source%" not found & goto Exit
if not exist "%FileList%" echo File list "%FileList%" not found & goto Exit
if not exist "%Target%" md "%Target%"

for /F "delims=" %%a in ('type "%FileList%"') do copy "%Source%\%%a" "%Target%"

:Exit
echo.
echo press the Space Bar to close this window.
pause > nul

Thanks.

[foxidrive]

You want to copy files that are in a text file?

What does your text file look like?

[carnagel]

You want to copy files that are in a text file?

What does your text file look like?

it just contains file names, not paths

filename.mp4
filename2.mp4

etc

[foxidrive]

Test this:

edited

Code: Select all

@echo off
set "Source=D:\mydirectory\myfiles"
set "Target=D:\tmp"
set "FileList=C:\Users\Administrator\Desktop\move.txt"
echo.

if not exist "%Source%" echo Source folder "%Source%" not found & goto Exit
if not exist "%FileList%" echo File list "%FileList%" not found & goto Exit
if not exist "%Target%" md "%Target%"

for /F "delims=" %%a in ('type "%FileList%"') do (
   for /f "delims=" %%b in ('dir "%Source%\%%a" /b /s /a-d ') do echo copying "%%b"&xcopy /b "%%b" "%Target%%%~pb" >nul
)
:Exit
echo.
echo press the Space Bar to close this window.
pause > nul

[carnagel]

Worked perfectly

Thanks very much for your help.