Name of a function

[pumi]

Hello,

how can I get the name of a function.

like this:

Code: Select all

:theFunction
   echo the name of the function is ???
goto:eof

thanks in advance, pumi

[Adrianvdh]

Hi
You would need to call the function

Code: Select all

call :theFunction

[penpen]

This should do it, if you have called it:

Code: Select all

@echo off
call :theFunction
goto:eof

:theFunction
   echo the name of the function is %0
goto:eof

penpen

Edit: Added code to full example.

[pumi]

thanks for your answer.
Can I get the name without the colon...like theFunction?

pumi

[foxidrive]

This should work:

Code: Select all

@echo off
call :theFunction
pause
goto:eof

:theFunction
   set func=%0
   echo the name of the function is %func:~1%
goto:eof

I thought this would work - interestingly it returns the main batch file path and name.

Code: Select all

@echo off
call :theFunction
pause
goto:eof

:theFunction
   echo the name of the function is %0 %~pnx0
goto:eof

[pumi]

I would like do this:

Code: Select all

@echo off
call :theFunction
echo theFunction
goto:eof

:theFunction
    set func=%0
    echo the name of the function is %func:~1%
    set "%func:~1%=the result"
goto:eof

I want to call the function and give a return value with the
same name as the function without the colon.
Unfortunately this does not work in this way.
Can you give me help again?
Thanks pumi

[aGerman]

The variable func is available in the main code as well.

Code: Select all

@echo off &setlocal

call :theFunction
echo back in main: %func%
pause
goto:eof

:theFunction
    set "func=%0"
    set "func=%func:~1%"
    echo the name of the function is %func%
goto:eof

Regards
aGerman

[penpen]

Unfortunately this does not work in this way.

You have just missed the %'s:

Code: Select all

@echo off
call :theFunction
echo %theFunction%
goto:eof

:theFunction
    set func=%0
    echo the name of the function is %func:~1%
    set "%func:~1%=the result"
goto:eof

penpen

[pumi]

this works for me now, thanks guys