Batch Script Improvement

[mydxbtester]

Daily, we generate around 1500+ to 2000+ call recordings and it's a very tedious to have those files converted to mp3 and stored to it's corresponding dated folder. The batch script below does the job but is there a way to refine/improve it? I mean it shouldn't copy (lame'd) and should skip all those files already existing in the !targetfolder! so as to preserve CPU resources.

Code: Select all

@echo off
setlocal enabledelayedexpansion
set FolderIncoming=C:\Original\PhoneCalls\AllCalls
set FileMask=201*.wav
set FolderSorted=C:\Backup\CompDrive - MyCompany\CallRecordings
Set LameLocation=C:\Program Files (x86)\Lame

for %%a in ("%FolderIncoming%\%FileMask%") do (
   set FileName=%%~na
   echo Processing '!FileName!' ...
   set TargetYear=!FileName:~0,4!
   set TargetFolder=!TargetYear!\!FileName:~0,10!
   if not exist "%FolderSorted%\!TargetFolder!" md "%FolderSorted%\!TargetFolder!"
   "%LameLocation%\lame.exe" -m j --cbr -b 320 -q 0 --lowpass 22.05 "%%a" "%FolderSorted%\!TargetFolder!\%%~na.mp3" 
)

Thank you.

[Squashman]

Use another IF NOT EXIST.

[mydxbtester]

If it's not too much to ask, can you show me how to do that as I'm not sure as to where to put that conditional statement.

[foxidrive]

Test this on some unimportant files:

Code: Select all

@echo off
setlocal enabledelayedexpansion
set FolderIncoming=C:\Original\PhoneCalls\AllCalls
set FileMask=201*.wav
set FolderSorted=C:\Backup\CompDrive - MyCompany\CallRecordings
Set LameLocation=C:\Program Files (x86)\Lame

for %%a in ("%FolderIncoming%\%FileMask%") do (
   set FileName=%%~na
   set TargetYear=!FileName:~0,4!
   set TargetFolder=!TargetYear!\!FileName:~0,10!
            if not exist "%FolderSorted%\!TargetFolder!\%%~na.mp3" (
               echo Processing '!FileName!' ...
               if not exist "%FolderSorted%\!TargetFolder!" md "%FolderSorted%\!TargetFolder!"
               "%LameLocation%\lame.exe" -m j --cbr -b 320 -q 0 --lowpass 22.05 "%%a" "%FolderSorted%\!TargetFolder!\%%~na.mp3" 
            )
)

[mydxbtester]

Perfect!!! Thank you.