DosTips.com

foxidrive wrote:Piping through a for loop is undocumented and unsupported

  for /l %k in (1,1,100000) do (
    (if %k==5 exit)
    echo %k
  )

jeb wrote:

foxidrive wrote:Piping through a for loop is undocumented and unsupported

Why this should be undocumented or unsupported?

It's simply a pipe, so both sides of the pipe are executed in a new cmd context (instead of a batch context).

foxidrive wrote:It fails in spectacular ways though. Put a pipe or two in a for /f command and pipe something into the for.

@echo off
echo hello|for /f %%A in ('"echo world|findstr ."') do @(
  findstr .
  echo %%A
)

echo goodbye|for /f %%A in ('"findstr .|findstr ."') do @echo %%A

hello
world
goodbye

dbenham wrote:

foxidrive wrote:It fails in spectacular ways though. Put a pipe or two in a for /f command and pipe something into the for.

I don't see the problem.
I also don't see what it is good for

Dave Benham

dbenham wrote:I also don't see what it is good for

@echo off
setlocal enableDelayedExpansion
if "%~1" equ ":tee" goto :tee

:lock
....
    for /f %%A in ("!yes!") do (
      find /n /v ""
      echo :END
      echo %%A
    ) >"%teeTemp%.tmp" | <"%teeTemp%.tmp" "%~f0" :tee %* 7>&1 >nul

foxidrive wrote:it worked fine for one pipe inside the for /f but when a second pipe was added it failed.
I tested it here and confirmed it in his test case, but I don't have the interest to devise multiple tests for it now.

@echo off
echo goodbye|for /f %%A in ('"findstr .|findstr .|findstr .|findstr .|findstr ."') do @echo %%A

goodbye

dbenham wrote:I'm don't quite follow the point you are making. But the number of pipes should not matter.

Nor do I see any reason to expect special documentation for such a situation.

einstein1969 wrote:this code [...] seem that execute the for /L without count to 100000 and not exit from current context.

foxidrive wrote:I can't be arsed looking for the thread - and I don't know which forum is was on - it worked fine for one pipe inside the for /f but when a second pipe was added it failed.

einstein1969 wrote:hi to all,

i have few questions for this code:

Code: Select all

@echo off

echo(|more|(

  for /l %%k in (1,1,100000) do (
    (if %%k==5 exit)
    echo %%k
  )

)

echo end

seem that execute the for /L without count to 100000 and not exit from current context.

It is safe?

Why the @echo off don't work?

einstein1969

@echo off
setlocal

set /A index=0, sum=0
echo/|(@echo off
   for /L %%? in (1,0,1) do (
      set /A index+=1, sum+=index > NUL
      echo !index!
      if !index! == 10 exit !sum!
   )
)
echo Returned value: %errorlevel%

HKEY_CURRENT_USER\Software\Microsoft\Command Processor\DelayedExpansion = 0x1

C:\> While.bat
1
2
3
4
5
6
7
8
9
10
Returned value: 55

Liviu wrote:Would you recall some context or keywords? I don't remember the issue, and a quick search finds nothing relevant. Several collectors of cmd oddities around here are curious and will be eternally grateful

Liviu

foxidrive wrote:I posted the issue in the message above yours.

foxidrive wrote:I found the test case that doesn't work. The first dir line shows the files (with echo on curiously) but the second fails.

Code: Select all

@echo off
dir /b /a-d | for /F "delims=" %%a in (' findstr "a" ') do echo %%a
pause
dir /b /a-d | for /F "delims=" %%a in (' findstr "a" ^| findstr "a" ') do echo %%a
pause

dir /b /a-d | for /F "delims=" %%a in ('" findstr "a" | findstr "a" "') do @echo.a=%%a_
dir /b /a-d | for /F "delims=" %%a in (' findstr "a" ^^^| findstr "a" ') do @echo.a=%%a_