Getting an ip address's hostname into a variable, using PING

[©opy[it]®ight]

I did a search before posting this message so here goes

I know that there are more ways to do this but since i'm far from an advanced scripter
i'm asking you guys (are there any females around? ) which code is most efficient/clean
to achieve the goal i want (i don't want to work with temporary files so i guess a FOR loop is necessary).

I use the following command:

ping -a -n 1 -w 0 %IP%

The default output has way too much info i don't want but i don't know how to skip/ignore or strip them from the result:

C:\Users\admin>ping -a -n 1 -w 0 74.125.79.94

Pingen naar ey-in-f94.1e100.net [74.125.79.94] met 32 bytes aan gegevens:
PING: verzenden mislukt. Algemene fout.

Ping-statistieken voor 74.125.79.94:
Pakketten: verzonden = 1, ontvangen = 0, verloren = 1
(100% verlies).

[©opy[it]®ight]

Hey Ed Dyreen, alles goed hoor

Thanks for the script, except that i want to get an external ip address's hostname, not a local one

edit: hah, you deleted your post already

[Squashman]

Very similar to the other code I posted to get the IP address from the hostname in your other thread.
Tokens will be 3 for you. Since I use english for my version of Windows the tokens is 2.

Code: Select all

for /f "tokens=3 delims= " %%G in ('ping -a -n 1 -w 0 74.125.79.94 ^| find "["') do set hostname=%%G

[Ed Dyreen]

'
Hey ©opy[it]®ight, alles goe

Code: Select all

@echo off

set "$hostnameOrIP=74.125.79.94"
set    "$.hostname="
set          "$.IP="

for /f "tokens=3,4delims=[] " %%a in (

       'ping "%$hostnameOrIP%" -n 1'

) do   if not defined $.hostname (

       set "$.hostname=%%~a"
       set       "$.ip=%%~b"
)

set "$"

pause
exit

I tried using an ip, but this doesn't returns the DNS for me.
Is that DNS in your hostfile or is that default behavior on your OS win7 ?

[©opy[it]®ight]

Very similar to the other code I posted to get the IP address from the hostname in your other thread.
Tokens will be 3 for you. Since I use english for my version of Windows the tokens is 2.

Code: Select all

for /f "tokens=3 delims= " %%G in ('ping -a -n 1 -w 0 74.125.79.94 ^| find "["') do set hostname=%%G

Thanks! Is there a way to make the script universal i.e. that it can be used regardless of the Windows version someone uses?
(i have yet to learn what tokens are and what they do )

found it: http://www.robvanderwoude.com/ntfortokens.php

Hey ©opy[it]®ight, alles goe

I tried using an ip, but this doesn't returns the DNS for me.
Is that DNS in your hostfile or is that default behavior on your OS win7 ?

No i just looked for an ip (used one from google) and typed the ping command.
My HOSTS file only has the default content/entries

[Squashman]

I tried using an ip, but this doesn't returns the DNS for me.

That's what the -a switch is for when using an IP.

[Squashman]

Thanks! Is there a way to make the script universal i.e. that it can be used regardless of the Windows version someone uses?
(i have yet to learn what tokens are and what they do )

I am not good with the language stuff. I leave that up to Ed and Liviu.

[Squashman]

I do like ED's solution better though as you can give the hostname or IP and it will give you back both. Just need to add the -a to the ping command on his code.

[©opy[it]®ight]

Hmm, true.. but if its not too much of a hassle to modify the script so that it can be used by more people around the world, i'm all ears

Ed? Ik ben benieuwd of je het voor elkaar weet te krijgen. In ieder geval bedankt voor de al gegeven oplossing!
(sorry if its not allowed to speak in another language than english hint: google translate )

[Ed Dyreen]

'
This can be used regardless the windows language or version.

Code: Select all

@echo off

call :hostName.resolve "ey-in-f94.1e100.net"
call :hostName.resolve "74.125.79.94"
call :hostName.resolve "0.0.0.1"
call :hostName.resolve ""

pause
exit

:hostName.resolve ( %1 )
:: (
       set "$.hostname="
             set "$.IP="

       for /f "tokens=1,2 delims=[]" %%a in (

              'ping /a "%~1" -n 1'

       ) do   if +%%~b neq + (

              for %%? in ( %%~a ) do set "$.hostname=%%~?"
              set "$.IP=%%~b"
       )
       echo. &set "$"
:: )
exit /b 0

Code: Select all

$.hostname=ey-in-f94.1e100.net
$.IP=74.125.78.94

$.hostname=ey-in-f94.1e100.net
$.IP=74.125.79.94

Omgevingsvariabele $ is niet gedefinieerd

$.hostname=ED-SERV-0
$.IP=192.168.1.10
Druk op een toets om door te gaan. . .

[©opy[it]®ight]

I believe that piece of code does it all
I barely understand what it does but it looks amazing and... it works!

(heb je er lang over gedaan om dit te leren?)

[Squashman]

I have come to appreciate Ed's style of code writing. He really likes to indent and space things out for readability.

[©opy[it]®ight]

Sure do(es)!

I've been playing with the code and it works a charm.
As i menioned before i'm not the only person that will use the script.

I host a webserver (sort of) that does one thing only, showing the connected client their external ip address/hostname.

Now, this works great for others, but when running this on my own computer/webserver, the script takes around 4 seconds to complete
(this only occurs when extracting the hostname from 192.168.0.1, as you see below):

Code: Select all

SET IP=192.168.0.1

for /f "tokens=1,2 delims=[]" %%a in ('ping -a -n 1 -w 0 %IP%') do if +%%~b neq + (for %%? in ( %%~a ) do set "HOSTNAME=%%~?")

The output i get:

ECHO is off (uit).

Whereas using 0.0.0.0 or 192.168.0.191 as IP address, it finishes almost instantly.

My question: Why does this happen/occur with one local IP, and not with others?

- ©opy[it]®ight

[Ed Dyreen]

'
Not sure, but I think ECHO is off (uit).

Code: Select all

@echo off
echo /?
set "HOSTNAME="
echo %HOSTNAME%
pause

Let me rephrase that, you are trying to echo a variable that isn't defined.
Apart from '@echo off', look for any 'echo ' statements in your batch and change them to 'echo.' or even better echo(.
Or just open your batch with notepad, press CTRL+H enter 'echo ' as the search string and 'echo.' as replacement string and select 'Alles vervangen'.

[©opy[it]®ight]

Ed Dyreen,

I couldn't find any empty echo statements. The ping command is simply not able to resolve a hostname for my router's IP 192.168.0.1, this is why the result(ing value) is empty/null.

Here are the results i got when pinging other local ip addresses:

C:\Users\admin>ping -a -n 1 -w 1 192.168.0.191

Pingen naar i7-2600K.lan_dn [192.168.0.191] met 32 bytes aan gegevens:

C:\Users\admin>ping -a -n 1 -w 1 192.168.0.121

Pingen naar Prutske [192.168.0.121] met 32 bytes aan gegevens: