can't write stream 3 when receiving input stream

[Ed Dyreen]

What a bummer, I was hoping to use stream 3 for warn/debug messages.

Code: Select all

@echo off & setlocal disableDelayedExpansion

   >&2 ( echo.redirecting to stream 2 succesfully )
   >&3 ( echo.redirecting to stream 3 succesfully )

< "%~f0" (

   >&2 ( echo.redirecting to stream 2 while receiving input succesfully )
   >&3 ( echo.redirecting to stream 3 while receiving input failed :^( )
)

pause
exit

Code: Select all

redirecting to stream 2 succesfully
redirecting to stream 3 succesfully
redirecting to stream 2 while receiving input succesfully
Het systeem kan niet naar het opgegeven apparaat schrijven.
Druk op een toets om door te gaan. . .

the error states; 'failed to write to given device'

[Aacini]

Why not just use CONsole device?

Code: Select all

@echo off & setlocal disableDelayedExpansion

   >&2 ( echo.redirecting to stream 2 succesfully )
   >CON ( echo.redirecting to CONSOLE succesfully )

< "%~f0" (

   >&2 ( echo.redirecting to stream 2 while receiving input succesfully )
   >CON ( echo.redirecting to CONSOLE while receiving input succesfully )
)

pause
exit

Antonio

[Ed Dyreen]

con is a device, not a stream, redirecting a device to another stream or device seams impossible. con output ends up on the console always, unlike streams which can be redirected to other streams over and over again.

Code: Select all

@echo off & setlocal disableDelayedExpansion

   ( ( >&2 ( echo.redirecting to stream 2 succesfully ) ) >&3 ) >&2
   >&3 ( echo.redirecting to stream 3 succesfully )

   ( >con ( echo.redirecting con to nul failed ) ) >nul

< "%~f0" (

   >&2 ( echo.redirecting to stream 2 while receiving input succesfully )
   >&3 ( echo.redirecting to stream 3 while receiving input failed :^( )
)

pause
exit

Code: Select all

redirecting to stream 2 succesfully
redirecting to stream 3 succesfully
redirecting con to nul failed
redirecting to stream 2 while receiving input succesfully
Het systeem kan niet naar het opgegeven apparaat schrijven.
Druk op een toets om door te gaan. . .

All streams end up on one or another device eventually.
stream 1 is usually used for normal output.
stream 2 is usually used for error messages.
stream 3 would be used for warnings, but this doesn't seam to work when an input stream is present.

[Ed Dyreen]

Anyways I think I figure it out

Code: Select all

@echo off & setlocal disableDelayedExpansion

   ( ( >&2 ( echo.redirecting to stream 2 succesfully ) ) >&3 ) >&2
   >&3 ( echo.redirecting to stream 3 succesfully )

   ( >con ( echo.redirecting con to nul failed ) ) >nul

4< "%~f0" (

   >&2 ( echo.redirecting to stream 2 while receiving input succesfully )
   >&3 ( echo.redirecting to stream 3 while receiving input succesfully )

   <&4 set /p $=
)

echo. "$=%$%_"

pause
exit

Code: Select all

redirecting to stream 2 succesfully
redirecting to stream 3 succesfully
redirecting con to nul failed
redirecting to stream 2 while receiving input succesfully
redirecting to stream 3 while receiving input succesfully
 "$=@echo off & setlocal disableDelayedExpansion_"
Druk op een toets om door te gaan. . .

but why

Anyways, you know you can redirect output from a function right.
That allows to quickly enable more details without having to dive into it eg;

Code: Select all

( %myFunction% arg1, arg 2 ) 3>nul

[Aacini]

I suggest you to read my last post on the thread about this topic...

Antonio