Open multiple websites at once

[Sciuruz]

Hi
I have this prodject at work, I want to open many and some webpages at once but my coding is not optimal and need help.
Sorry for cutting out all the websites but the sit would not lett me have more than two in the writing
How I want it to work:

- open one site at the time (works)
- open all sites at once (works) but bad coding
- open webpage 1, 3 and 4 at a time (don't know how to do)

Here is my prodject:

@echo off
color 0a
echo ABB's mest brukte websider. Gi beskjed om det mangler noen.
echo 1= VG
echo 2= Dagbladet
echo 3= Itavisen
echo 4= Finn
echo 5= Qxl
echo 6= Cabinweb
echo 7= Inside ABB
echo 8= CMG Office
echo 9= All
echo.
set/p "number=-->"
if %number%==1 GOTO 1
if %number%==2 GOTO 2
if %number%==3 GOTO 3
if %number%==4 GOTO 4
if %number%==5 GOTO 5
if %number%==6 GOTO 6
if %number%==7 GOTO 7
if %number%==8 GOTO 8
if %number%==9 GOTO 9
:1
start http://www.vg.no
goto end
:2
start website
goto end
:3
start website
goto end
:4
start website
goto end
:5
start website
goto end
:6
start website
goto end
:7
start website
goto end

:8
start website
goto end
:9
@echo Off

Start "C:\Program Files\Internet Explorer\iexplore.exe" "about:blank"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "http://www.vg.no"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
Start "C:\Program Files\Internet Explorer\iexplore.exe" "website"
:end




I want the menu to pick from thees number instead of putting the websites another time in menu 9 in the bottom

if %number%==1 GOTO 1
if %number%==2 GOTO 2
if %number%==3 GOTO 3
if %number%==4 GOTO 4
if %number%==5 GOTO 5
if %number%==6 GOTO 6
if %number%==7 GOTO 7
if %number%==8 GOTO 8
if %number%==9 GOTO 9

If you have other sugestions plece lett me know I'm open for new ways to do thing

Thanks in adwanse

[Ed Dyreen]

Welcome Sciuruz

Code: Select all

@echo off &color 0a &setlocal enableDelayedExpansion

set "$1.name=VG"
set "$1.link=about:blank"
set "$2.name=Dagbladet"
set "$2.link=http://www.vg.no"
set "$3.name=Itavisen"
set "$3.link=website"
set "$4.name=Finn"
set "$4.link=website"
set "$5.name=Qxl"
set "$5.link=website"
set "$6.name=Cabinweb"
set "$6.link=website"
set "$7.name=Inside ABB"
set "$7.link=website"
set "$8.name=CMG Office"
set "$8.link=website"

<:loop.getTotal <nul set /a $count = 0
:: (
     set /a $count += 1
     if defined $!$count!.name goto :loop.getTotal
     set "$!$count!.name=All"
     set /a $!$count!.link = $count - 1
:: )

:loop.getSelection
:: (
     cls
     echo ABB's mest brukte websider. Gi beskjed om det mangler noen.
     for /l %%i in ( 1, 1, !$count! ) do echo.%%i= !$%%i.name!
     echo.
     set /p "number=-->"
     if !number! lss 1 goto :loop.getSelection
     if !number! gtr !$count! goto :loop.getSelection
:: )

if !number! neq !$count! (

     echo.start "!$%number%.name!" "C:\Program Files\Internet Explorer\iexplore.exe" "!$%number%.link!"

) else for /l %%i in ( 1, 1, !$%$count%.link! ) do (

     echo.start "!$%%i.name!" "C:\Program Files\Internet Explorer\iexplore.exe" "!$%%i.link!"
)
pause

goto :loop.getSelection

[Sciuruz]

Thanks for the welcome note and the coding aswell


I'll try this right away and I'll let you know how it works out

[aGerman]

Another one:

Code: Select all

...
set/p "number=-->"
for %%i in (%number%) do call :%%i
goto :eof

:1
start website
goto :eof

etc ...

separate the numbers by spaces, commas or semi colons.

Regards
aGerman