~ How to get Unique GUID value in Batch? ~

[Dos_Probie]

Trying to extract network info (see Working and Non-Working Scripts Below), only problem is it needs the {GUID} and I don't know that going in as it changes from computer to computer, How can I retrieve the {GUID} value and then echo back the correct information?
Thanks for the help..Dos_Probie

Some examples which are similiar but not the same..
viewtopic.php?f=3&t=1734
http://mykbit.blogspot.com/2009/11/unin ... emote.html

Code: Select all

@echo off&color e
SETLOCAL ENABLEEXTENSIONS
title,==NETWORK INFORMATION!==

::WORKING-Once I have the Correct GUID

:: Query Wireless Profile Name with Exsisting GUID then echo back Info::
set qry=reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\{53EF403B-0E9C-4BE6-BCCF-67A45439006C}" /v ProfileName
set fnd=findstr /I /L /C:"REG_SZ"
for /f "Tokens=2*" %%u in ('%qry%^|%fnd%') do (@echo Your Profile Name Is: %%v)
echo.
pause


::NOT WORKING-This is what I have so far to find {GUID} but it just flashes error..
for /f "tokens=7 delims=\" %%a in ('reg query HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles ^| FIND "{"') do
for /f "tokens=2,*" %%c in ('reg query HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%%a ^| find /i "ProfileName"') do
echo %%d,%%a>>PROFILE.NAME.txt
echo.
pause
exit

[foxidrive]

It errors because "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" does not have quotes around it.

[Dos_Probie]

It errors because "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" does not have quotes around it.

Foxi, I thought the same thing but when I add quotes still flashes and not working..
Have you got example that will work?

Code: Select all

::NOT WORKING-This is what I have so far to find {GUID} but it just flashes error..
for /f "tokens=7 delims=\" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do
for /f "tokens=2,*" %%c in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles"\%%a ^| find /i "ProfileName"') do
echo %%d,%%a>>PROFILE.NAME.txt
echo.
pause

[foxidrive]

The mistake you made was to forget the DO ( ... ) parentheses.

This works here:

Code: Select all

@echo off
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do (
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%%~nxa" ^| FIND "ProfileName"') do echo %%~nxa,%%c
)
pause

[Dos_Probie]

Ok, Gotcha...Thanks!
getting closer that lists Both GUIDs, anyway to just list one ?

[foxidrive]

First or second?

is this for your own machine or for distribution - do you have to handle more than 2 GUIDs?

[Dos_Probie]

The First GUID and only need to handle one..

[foxidrive]

This works here:

Code: Select all

@echo off
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do set var=%%~nxa&goto :gotit
:gotit
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%var%" ^| FIND "ProfileName"') do echo %var%,%%c
pause

[Dos_Probie]

This works here:

Code: Select all

@echo off
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do set var=%%~nxa&goto :gotit
:gotit
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%var%" ^| FIND "ProfileName"') do echo %var%,%%c
pause

Thanks for the code Foxi, it gives Both the Guid and the Network name.. anyway to just show
the Network Name:

[Dos_Probie]

What exactly does the %%~nxa variable do ?

[foxidrive]

This works here:

Code: Select all

@echo off
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do set var=%%~nxa&goto :gotit
:gotit
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%var%" ^| FIND "ProfileName"') do echo %var%,%%c
pause

Thanks for the code Foxi, it gives Both the Guid and the Network name.. anyway to just show
the Network Name:

Remove %var%, from the echo command.

What exactly does the %%~nxa variable do ?

It returns the last part of a string where the sting has \ or / as delimiters. It returns the name and extension, if it has one. That is what the nx means in the variable - check the help FOR /? and read the last couple of pages for the other metavariables.

[Dos_Probie]

Ok, Thanks got it!

Code: Select all

@echo off&color e
SETLOCAL ENABLEEXTENSIONS
title,==NETWORK INFORMATION!==

:: ISP Domain
for /f "tokens=2 delims=:" %%# In ('IPConfig /all^|Find "DNS Suffix Search List"') Do (
for %%$ In (%%#) Do Set ISPDomain=%%$) 
echo=Your ISP Domain Is: %ISPDomain% 
echo.

:: IP Address
for /f "tokens=2 delims=:" %%# In ('IPConfig^|Find "IPv4"') Do ( 
Call :Addy %%#) 
:Addy 
Set IP=%1 
Echo=Your IP Address Is: %IP%
echo.

:: Network Profile Name
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles" ^| FIND "{"') do set var=%%~nxa&goto :gotit
:gotit
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\software\microsoft\windows nt\currentversion\networklist\Profiles\%var%" ^| FIND "ProfileName"') do echo Your Active Profile Name Is: %%%c

pause>nul

[Dos_Probie]

Foxi, I need to use the Second guid on another query so How did you determine to use either the first guid or the second guid ?

[foxidrive]

Take out the &goto :gotit and it will take the last one. %var% will contain the information.



If there will ever be three or more then more extensive coding is needed.

[Dos_Probie]

Ok, Thanks .. That's What I had already figured out b4 you posted..The below code has multiple
guids +3 so shows more than one..

Code: Select all

@echo off&color e
SETLOCAL ENABLEEXTENSIONS
title,==NETWORK INFORMATION!==

::cks online or offline

::Lists both 192.xxx.x.xx and 0.0.0.0 (Need only the 192.xxx)
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\services\Tcpip\Parameters\Interfaces" ^| FIND "{"') do (
for /f "tokens=2,*" %%b in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\services\Tcpip\Parameters\Interfaces\%%~nxa" ^| FIND "DhcpIPAddress"') do echo %%c
)